Verified answer

Réponse :

Explications étape par étape :

Tu peux télécharger un tableur sur un PC windows

https://www.openoffice.org/fr/Telecharger/

ou, c'est un peu différent, travailler dans google sheets, sans rien installer.

L'avantage de OpenOffice : il admet les docs excel (suffixe .xlsx)

Il est important de comprendre les formules utilisées

Explications :

Numéroter de 1 à 2000 colonne A

Je note 1 dans A8

En dessous je note =A8+1 dans la cellule A9

Je sélectionne A9 copier

Je sélectionne A10:A2007 coller

Simuler un dé 6 faces colonne B et C

case (on dit cellule ) B8 :

formule =ENT(6*ALEA( )+1)

ALEA() fonction

documentation : "Renvoie un nombre réel aléatoire distribué de manière symétrique supérieur ou égal à 0 et inférieur à 1. Un nouveau nombre réel aléatoire est renvoyé chaque fois que la feuille de calcul est recalculée."

Comprendre :

1. le résultat est dans [0 ; 1[   (nombre à virgule)
2. Si on multiplie par 6 , le résultat est dans [0 ; 6[
3. Si on ajoute 1 , le résultat est dans [1 ; 7 [
4. Si on prend la partie entière, le résultat est dans {1, 2, ..., 5, 6 }

Cette formule se copie pour le dé n°2

  case B8  Copier

  case C8  Coller

On en fait la somme dans la colonne suivante

Case D8 formule   =SOMME(B8:C8)

Ensuite : B8 à D8 : Sélection Copier

B9 à D2007 : Coller

Fréquences colonne G

Dans la case G8, formule : =NB.SI(D$8:D$2007;F8)/NB(D$8:D$2007)

C'est chaud !

Explication : oublions les $ pour l'instant :

G8, formule : =NB.SI( D8:D2007;F8) / NB(D8:D2007)

OK, d'abord NB.SI( D8:D2007;F8)

on compte dans la zone D8:D2007 .. toutes les valeurs égales à F8

Dans F8, j'ai mis : la somme possible 2

Donc, on recherche tous les 2 (cellule F8) dans la colonne D (colonne des sommes) entre les lignes 8 et 2007  (limites incluses)

Ca c'est le nombre d'occurences de tirages qui donnent 2. Et il faut diviser ce nombre par le nombre de tirages (2000) J'ai préféré

compter le nombre de cases avec NB(D8:D2007)

OK, tu as compris la formule de la fréquence.

LE PROBLEME DU DOLLAR

Une formule excel fait très souvent référence à des cellules par leur adresse.

Mais ces formules sont RELATIVES. Explication :

cellule G8, formule : =NB.SI( D8:D2007;F8) / NB(D8:D2007)

Excel comprend cela comme

D8 : cellule de la même ligne 3 cases à gauche

D2007 : cellule 3 cases à gauche, et 1999 lignes plus bas

F8 : cellule de la même ligne 1 case à gauche

Et donc, quand je vais copier cela à la ligne en dessous , xecel

va vouloir MAINTENIR la relativité en modifiant les adresses

cellule G9, formule : =NB.SI( D9:D2008;  F9) / NB(D9:D2008)

Pas bon ! Il faut BLOQUER les n° de lignes pour la zone

D8:D2007

Pour ce faire, on fait précéder ces n° de lignes par $

cellule G8, formule : =NB.SI( D$8:D$2007;F8) / NB(D$8:D$2007)

si on la copie en dessous :

cellule G9, formule : =NB.SI( D$8:D$2007;F9) / NB(D$8:D$2007)

Voilà, tu as toutes les formules

REMARQUE :

Quand tu actualise la feuille, ou que tu la recalcules par la fonction F9,

tous les alea sont recalculés

LES Commentaires

Case F21

=CONCATENER("La probabilité de la somme la plus fréquente est environ ";MAX(G8:G18)*100;" %")

On "colle" un texte, une valeur, un texte

La valeur : c'est 100 fois le max des fréquences de G8 à G18

Case F23

C'est la plus compliquée

=CONCATENER("Il faut parier sur la somme ";INDEX(F8:F18;EQUIV(MAX(G8:G18);G8:G18)))

Explication de MAX(G8:G18) :

Plus grande valeur parmi toutes les fréquences

OK, admettons que cette valeur soit 0,17...  (soit  17%) sur la ligne de la somme 7, la 6ème ligne du tableau des fréq.

Continuons :

=CONCATENER("Il faut parier sur la somme ";INDEX(F8:F18;EQUIV(MAX(G8:G18) ; G8:G18) ) )

Explication de EQUIV(MAX(G8:G18) ; G8:G18)

donne le rang du MAX des fréq. dans la liste des fréquences G8:G18

rang de 1 à .. nombre de fréquences . Dans notre exemple, ça renvoie 6

car c'est la 6ème ligne

Et finalement : INDEX(F8:F18 ; EQUIV(MAX(G8:G18) ; G8:G18) )

Index va chercher dans l'intervalle F8:F18 la valeur à la 6ème ligne (dans notre exemple) .Ca va donner 7.

Pour le tableau graphique :

Je sélectionne les valeurs des fréquences, cette seule colonne avec le titre . Je fais "Insertion" Puis graphe ....

Puis dans le menu Outils graphique, je vais chercher "Sélection des données" de façon à choisir "Modifier" valeurs axe x 'abscisses)